DE150-102N02A Datasheet, PDF (3/3 Pages) List of Unclassifed Manufacturers – N-Channel Enhancement Mode Avalanche Rated Low Qg and Rg High dv/dt Nanosecond Switching RF Power MOSFET

Directed Energy, Inc.
An IXYS Company
DE150-102N02A
RF Power MOSFET
102N02A DE-SERIES SPICE Model
The DE-SERIES SPICE Model is illustrated in Figure 1. The model is an expan-
sion of the SPICE level 3 MOSFET model. It includes the stray inductive terms
L_G, L_S and L_D. Rd is the R_DS(ON) of the device, Rds is the resistive leakage term.
The output capacitance, C_OSS, and reverse transfer capacitance, C_RSS are mod-
eled with reversed biased diodes. This provides a varactor type response nec-
essary for a high power device model. The turn on delay and the turn off delay
are adjusted via Ron and Roff.
Figure 1 DE-SERIES SPICE Model
This SPICE model may be downloaded as a text file from the DEI web site at
www.directedenergy.com/spice.htm
Net List:
*SYM=POWMOSN
.SUBCKT 102N02A 10 20 30
* TERMINALS: D G S
* 1000 Volt 1.5 Amp 11.0 ohm N-Channel Power MOSFET 10-30-2001
M1 1 2 3 3 DMOS L=1U W=1U
RON 5 6 4.0
DON 6 2 D1
ROF 5 7 2.0
DOF 2 7 D1
D1CRS 2 8 D2
D2CRS 1 8 D2
CGS 2 3 500Pf
RD 4 1 11
DCOS 3 1 D3
RDS 1 3 5.0MEG
LS 3 30 .5N
LD 10 4 1N
LG 20 5 1N
.MODEL DMOS NMOS (LEVEL=3 VTO=3 KP=.3)
.MODEL D1 D (IS=.5F CJO=10P BV=100 M=.5 VJ=.2 TT=1N)
.MODEL D2 D (IS=.5F CJO=100P BV=1000 M=.6 VJ=.6 TT=1N RS=10M)
.MODEL D3 D (IS=.5F CJO=150P BV=1000 M=.35 VJ=.6 TT=400N RS=10M)
.ENDS
Doc #9200-0239 Rev 1
© 2001 Directed Energy, Inc.
Directed Energy, Inc.
An IXYS Company
2401 Research Blvd., Suite 108
Fort Collins, CO USA 80526
970-493-1901 Fax: [phone]
Email: [e-mail]
Web: http://www.directedenergy.com